Auxiliary Materials for Perfect Parallelepipeds Exist

by Jorge Sawyer and Cliff Reiter

len2[X_]:=Factor[X.X]

len[X_]:=Sqrt[len2[X]]

lena[u_,v_,w_]:={{"u",len[u]},{"v",len[v]},{"w",len[w]},
				{"u+v",len[u+v]},{"u-v",len[u-v]},{"u+w",len[u+w]},{"u-w",len[u-w]},{"v+w",len[v+w]},{"v-w",len[v-w]},
{"u+v+w",len[u+v+w]},{"u+v-w",len[u+v-w]},{"u-v+w",len[u-v+w]},{"u-v-w",len[u-v-w]}}

Assemble[x1_,x2_,x3_,d23_,d13_,d12_]:=Block[{rho,c23,c13,c12,u,v,w},
c12=(x1^2+x2^2-d12^2)/(2 x1 x2);
c13=(x1^2+x3^2-d13^2)/(2 x1 x3);
c23=(x2^2+x3^2-d23^2)/(2 x2 x3);
rho=(c23-c12 c13)/(Sqrt[1-c12^2]Sqrt[1-c13^2]);
u=x1{1,0,0};
v=x2{c12,Sqrt[1-c12^2],0};
w=x3{c13,rho Sqrt[1-c13^2],Sqrt[1-rho^2]Sqrt[1-c13^2]};
{u,v,w}]

Verification of Theorem 1

{u,v,w}=Assemble[271,106,103,101,266,255]

lena[u,v,w]

Verification of Theorem 4

{u,v,w}=Assemble[x1,x2,x3,d23,d13,d12]

lena[u,v,w]